PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> PREFIX
rdfs:<http://www.w3.org/2000/01/rdf-schema#> PREFIX owl:
<http://www.w3.org/2002/07/owl#> PREFIX corvus:
<http://krauthammerlab.med.yale.edu/ontologies/corvus-mapping.owl#>
PREFIX dm:
<http://www.cs.ucl.ac.uk/staff/a.gonzalezbeltran/owl/domainmodel.owl#>
PREFIX nci: <http://ncicb.nci.nih.gov/xml/owl/EVS/Thesaurus.owl#>
PREFIX sm:
<http://www.cs.ucl.ac.uk/staff/a.gonzalezbeltran/owl/semanticmetadata.owl#>
PREFIX caarray:
<http://www.cs.ucl.ac.uk/staff/a.gonzalezbeltran/owl/caarray2_1.owl#>
PREFIX catissuesuite:
<http://www.cs.ucl.ac.uk/staff/a.gonzalezbeltran/owl/catissuesuite1.owl#>
PREFIX catissuecore:
<http://www.cs.ucl.ac.uk/staff/a.gonzalezbeltran/owl/catissuecore1_2.owl#>

SELECT DISTINCT ?hybridizationName ?diagnosis
WHERE
{   

    # Find all Sources that are derived from a Specimen.
    ?source
        corvus:derived_from ?specimen.

    # Traverse from Source to Hybridization.
    ?source
        caarray:Source_samples_Sample ?sample.
    ?sample
        caarray:Sample_extracts_Extract ?extract.
    ?extract
        caarray:Extract_labeledExtracts_LabeledExtract ?labeledExtract.
    ?labeledExtract
        caarray:LabeledExtract_hybridizations_Hybridization ?hybridization.
    ?hybridization
        dm:umlAttributeCollection ?hybridizationNameAtt.

    # Extract the name of the Hybridization
    ?hybridizationNameAtt
        rdf:type ?hybridizationNameAttType .
    ?hybridizationNameAttType
        rdfs:subClassOf ?hnaSmr .
    ?hnaSmr
        rdf:type owl:Restriction;
        owl:onProperty sm:semanticMetadataCollection;
        owl:someValuesFrom nci:Name.

    ?hybridizationNameAtt
        dm:datatype ?hybridizationName.

    # Find all Specimen Collection Groups that are linked to our Specimens.
    ?scg
        catissuecore:SpecimenCollectionGroup_specimenCollection_CellSpecimen ?specimen.

    # Extract the Clinical Diagnosis at the time the 
    # Specimen Collection Group was collected.
    ?scg
        dm:umlAttributeCollection ?scgDiagnosisAtt.
    ?scgDiagnosisAtt
        rdf:type ?scgDiagnosisAttType .
    ?scgDiagnosisAttType
        rdfs:subClassOf ?scgdaSmr .
    ?scgdaSmr
        rdf:type owl:Restriction;
        owl:onProperty sm:semanticMetadataCollection;
        owl:someValuesFrom nci:Clinical_Diagnosis.
    ?scgDiagnosisAtt
        dm:datatype ?diagnosis.
}