breed [pseudo pseudos]
breed [epi-cell epi-cells]
breed [epi-affector epi-affectors]  ;; cental cluster of epi-cells to model focal injury with signal diffusion


globals  [mucous-layer
          epi-cell-layer
          systemic-layer
          step
          hour
          total-mucous
          total-tight-junctions
          total-bacteria
          total-exotoxin-lumen
          total-exotoxin-systemic
          total-pseudos
          total-epi-cells
         ]
     
patches-own  [mucous
              bacteria
              nutrient
              dynorphin
              interferon
              adenosine
              phosphate
              phosphate-lumen
              iron
              iron-lumen
              HQNO
              PQS-Fe
              PQS-Fe-rhamno
              PA1-lectin
              Mucinase
              RhlRI
              rhamnolipid
              quorum-signal
              exotoxin-lumen
              exotoxin-systemic
              tight-junction
              permeability
              p-inosine
              p-PQS
             ]
            
turtles-own  [life
              quorum
              i-interferon
              i-dynorphin
              i-adenosine
              i-HQNO
              i-PQS-Fe
              i-rhamnolipid
              i-PA1-lectin
              i-mucinase
              i-RhlR1
              apoptosis
              innate-immune
              mvfr
              mvfr-reg
              mvfr-count
              inosine
              lecA
              lecA-reg
              lecA-count
              adenosine-deaminase
              luxbox
              i-RhlRI
              oprF
              phoB-Pi
              phoB
              phobox
              phobox-reg
              iPi
              phoR
              PstS
              i-PQS
              pqsABCDE
              TNA
              pre-exotoxin
              adhere
              make-exotoxin
              HIFa
              grow-colony
              cell-divide
              TJ-counter
              pre-TJ
              TJ-level
              stress-response
              sense-pseudo
              iron-sense
              pyoverdin
             ]
    
to setup

    ca
    if random-runs = false
    [random-seed 1
    ]
    set step 0
    set hour 0
    set phosphate-deplete false
    set enteral-phosphate false
    set mode "health"
    
    ask patches
    [set mucous 90 + random 10    ;; small variation in mucous thickness, determines carrying capacity of environment for bacteria
     set bacteria mucous          ;; initial conditions bacteria fill carrying capacity, limited resources for pathogen population growth
     set total-bacteria bacteria + count pseudo
     set dynorphin 0
     set interferon 0
     set adenosine 0
     set phosphate 100
     set iron 20
     set phosphate-lumen 0
     set HQNO 0
     set PQS-Fe 0
     set PQS-Fe-rhamno 0
     set rhamnolipid 0
     set PA1-lectin 0
     set mucinase 0
     set RhlRI 0
     set exotoxin-lumen 0
     set exotoxin-systemic 0
     set tight-junction 100
     sprout 1
     [set breed epi-cell
      set color blue
      set shape "square"
      set size 0.3
      set life 100
      set TJ-counter random 12
      set pre-TJ 100
      set TJ-level 100
     ]
     if (pxcor > -4 and pxcor < 4 and pycor > -4 and pycor < 4)
     [sprout 1
      [set breed epi-affector
       set color sky
       set shape "square"
       set size 0.3
       set life 100
      ]
     ]
    set-background
    ]
    create-pseudo initial-pseudo-population    ;; starting population of pathogens can be regulated at interface
    [set color red
     set shape "pentagon"
     set size 0.7
     setxy random-pxcor random-pycor
     set life 100
     set grow-colony false    ;; not in growth phase during initial colonization
    ]
end
             
to go
    tick
    if step = 12
    [set hour hour + 1
     set step 0
    ]
    set step step + 1
    
    ask pseudo
    [pseudo-function
    ]
  
    diffuse-solutes
    
    ask patches
     [set-background
      phosphate-metabolism
      iron-metabolism
      toxin-function
      flora-function
      set total-bacteria max list 0 bacteria + count pseudo
     ]
    
    ask epi-cell
    [if epi-effect = "focus"          ;; central cluster of epithelial cells respond to host signal to produce focal injury signal
     [if (pxcor > -4 and pxcor < 4 and pycor > -4 and pycor < 4)
      [epi-cell-function
      ]
     ]
     if epi-effect = "all"
     [epi-cell-function
     ]
    ]
    do-plots
    if data = true
    [data-collect
    ]
    
end

to epi-cell-function
if life = 0
  [die
  ]
if apoptosis = true
  [set life max list 0 (life - 1)    ;; "red death" toxin induces epithelial apoptosis at 6hr post-injection in mice
  ]
if PQS-Fe-rhamno > 10            ;; accumulation of toxin prior to induction of apoptosis
  [set PQS-Fe-rhamno max list 0 (PQS-Fe-rhamno - 10)
   set apoptosis true
  ]
if mode = "inflammation"
  [if random 3 = 1
   [set interferon interferon + 1
   ]
  ]
if stress-response = true
[set dynorphin dynorphin + i-dynorphin
 set i-dynorphin 0
 ifelse sense-pseudo = true 
   [set i-dynorphin 3
   ]
   [set i-dynorphin 1
   ]
]

 if count pseudo-on patch-here > 0
 [set sense-pseudo true
 ]

if mode = "stress" or mode = "ischemia"
  [set stress-response true
  ]
  
if i-adenosine >= 1
  [set adenosine adenosine + 1 
   set i-adenosine i-adenosine - 1
  ]
set i-adenosine max list 0 i-adenosine + HIFa 
ifelse mode = "ischemia-limited" or mode = "ischemia" ;; representation of HIFa from publication, represent transient ischemia
   [set HIFa random 3
    set life max list 0 life - 0.1
   ]
   [set HIFa 0
    set life max list 100 life + 0.1
   ]
if mode = "health"
  [set HIFa 0
  ]
  
ifelse adenosine >= 1
[set TJ-level 100
]
[set TJ-level 100 - ((100 * PA1-lectin) / (5 + PA1-lectin))
]
TJ-function
end

to pseudo-function
if i-PA1-lectin > 0        ;; PA1 lectin causes adhesion to epi cell layer
 [set adhere true]
ifelse adhere = true
 [move-to patch-here]
 [rt random 45
  lt random 45
  fd 1
 ]
iron-scavenge
reproduce
if quorum = true      ;; Pseudomonas needs to sense quorum before virulence expression
[mvfr-function
 lecA-function
 opioid-response
 immune-reponse
 ischemia-response
 phosphate-response
]
if quorum-signal > quorum-threshold  ;; threshold for quorum sensing at interface control  
[set quorum true
]
set quorum-signal min list 10 quorum-signal + random 5 ;; constituitive release of generic quorum signal
end
  
to diffuse-solutes
    diffuse dynorphin 0.95
    diffuse interferon 0.9
    diffuse adenosine 0.9
    diffuse PA1-lectin 0.3
    diffuse p-inosine 0.9
    diffuse phosphate 1.0
    diffuse HQNO 0.9
    diffuse p-PQS 0.9
    diffuse PQS-Fe 0.9
    diffuse PQS-Fe-rhamno 0.3
    diffuse quorum-signal 0.9
  ask patches
   [set PA1-lectin PA1-lectin * 0.95
    set interferon interferon * 0.95
    set p-inosine p-inosine * 0.95
    set dynorphin dynorphin * 0.95
    set adenosine adenosine * 0.90
    if interferon < 0.5
    [set interferon 0]
    if adenosine < 0.5
    [set adenosine 0]
    if p-inosine < 0.5
    [set p-inosine 0]
    if dynorphin < 0.5
    [set dynorphin 0]
    if PA1-lectin < 0.5
    [set PA1-lectin 0]
   ]
end

to toxin-function
  set PQS-Fe-rhamno PQS-Fe-rhamno + PQS-Fe
  set PQS-Fe 0
  if tight-junction <= 50
  [set exotoxin-systemic exotoxin-systemic + (0.01 * exotoxin-lumen)
   set exotoxin-lumen exotoxin-lumen * 0.99
  ]
end

to opioid-response
if mvfr-reg = true              ;; delay expression of mvfr
[set mvfr-count mvfr-count + 1
]
if dynorphin >= 1
[set mvfr-reg true
]
set i-dynorphin min list 10 (dynorphin / 5)  ;; sets magnitude of response based on maximum dynorphin concentration
end

to immune-reponse
 set luxbox RhlRI
 set RhlRI oprF
 set oprF max list oprF interferon    ;; sets magnitude of response based on maximum interferon concentration
end

to ischemia-response
set inosine min list 20 (adenosine-deaminase * 2) ;; inosine 2x potent as adenosine
set adenosine-deaminase i-adenosine
set i-adenosine max list i-adenosine adenosine  ;; sets magnitude of response based on maximum adenosine concentration
end

to phosphate-response
 if phobox-reg = true
 [set mvfr-count mvfr-count + 1
 ]
 set phobox phoB-Pi
 set phoB-Pi phoB
 set phoB phoR
 set phoR max list 0 PstS
 if phosphate < 90                      ;; hypophosphatemia sets magnitude of virulence response via PstS
 [set PstS min list 10 (90 - phosphate)
  set phobox-reg true
 ]
end     

to lecA-function
 if lecA-reg = true
 [set lecA-count lecA-count + 1
 ]
 if luxbox + inosine + i-PQS > 0
 [set lecA-reg true
 ]
 if lecA-count > 40
 [set PA1-lectin PA1-lectin + min list 10 random i-PA1-lectin
  set i-PA1-lectin max list 0 lecA 
  set lecA min list 30 (inosine + luxbox + i-PQS)
  set i-PQS max list 0 i-PQS - 1
 ]
end

to mvfr-function
 set PQS-Fe PQS-Fe + i-PQS-Fe
 set HQNO HQNO + i-HQNO
 set i-PQS-Fe max list 0 min list pyoverdin i-PQS
 set i-PQS max list 0 pqsABCDE
 set i-HQNO max list 0 pqsABCDE
 set pqsABCDE max list 0 TNA
 set TNA max list 0 mvfr
 ifelse mvfr-count > 80
 [set mvfr min list 20 i-dynorphin + phobox
 ]
 [set mvfr 0
 ]
end


to phosphate-metabolism
 set phosphate min list 100 phosphate + (phosphate-lumen * 0.25) ;; mucosal phosphate can be repleted by luminal phosphate repletion
 set phosphate-lumen phosphate-lumen * 0.75
 if phosphate-deplete = true
 [set phosphate phosphate * (990 + random 10) / 1000
 ]
 if enteral-phosphate = true
 [set phosphate-lumen min list 20 phosphate-lumen + random 3
 ] 
end

to iron-scavenge
ifelse iron-sense = true
[set pyoverdin min list 10 (pyoverdin + 1)
]
[set pyoverdin max list 0 (pyoverdin - 1)
]
ifelse iron <= 10
[set iron-sense true
]
[set iron-sense false
]
end

to iron-metabolism
 set iron min list 20 iron + (iron-lumen * 0.25) ;; mucosal phosphate can be repleted by luminal phosphate repletion
 set iron-lumen iron-lumen * 0.75
 if iron-deplete = true
 [set iron iron * (990 + random 10) / 1000
 ]
 if enteral-iron = true
 [set iron-lumen min list 10 iron-lumen + random 3
 ] 
end

to reproduce
if mucous - bacteria - count pseudo-on patch-here > 20
[set grow-colony true
]
if cell-divide > 20
 [set cell-divide 0
  set grow-colony false
  hatch 1
  [set heading random 360      ;; new agents spread out at random
   fd 1
   set adhere true
   set grow-colony false 
  ]
 ]
if grow-colony = true
[set cell-divide cell-divide + 1
]
end
 
to TJ-function
if TJ-counter = 18    ;; halflife for occludin ~ 1.5 hours
[set TJ-counter 0
 set tight-junction  pre-TJ
 set pre-TJ TJ-level
]
set TJ-counter TJ-counter + 1
end

to flora-function
set bacteria min list mucous bacteria * (1.02 - min list 0.01 (HQNO / 1000)) ;; normal population growth rate affected by HQNO toxin
set bacteria max list 0 bacteria - random 3    ;; constant clearance rate keeps bacteria population stable with normal growth rate
end

to set-background
 if background = "mucous"
 [set pcolor scale-color yellow mucous 0 200
 ]
 if background = "permeability"
 [set pcolor scale-color 129 tight-junction 0 200
 ]
 if background = "quorum"
 [set pcolor scale-color orange quorum-signal 0 100
 ]
 if background = "bacteria"
 [set pcolor scale-color brown bacteria 0 300
 ]
 if background = "phosphate"
 [set pcolor scale-color green phosphate 0 250
 ]
 if background = "epi-cells"
 [set pcolor white]
 if background = "interferon"
 [set pcolor scale-color gray interferon 10 0
 ]
 if background = "adenosine"
 [set pcolor scale-color gray adenosine 10 0
 ]
  if background = "inosine"
 [set pcolor scale-color gray p-inosine 10 0
 ]
  if background = "dynorphin"
 [set pcolor scale-color gray dynorphin 50 0
 ]
end

to do-plots
 set-current-plot "Barrier permeability"
 set-current-plot-pen "PA1-lectin"
 plot (sum [PA1-lectin] of patches) / 100
 set-current-plot-pen "tight-junction"
 plot sum [tight-junction] of patches / count patches
 
 set-current-plot "Iron"
 set-current-plot-pen "iron"
 plot sum [iron] of patches / count patches
 set-current-plot-pen "iron-sense"
 plot count pseudo with [iron-sense = true] / count pseudo
 set-current-plot-pen "pyoverdin"
 plot sum [pyoverdin] of pseudo / count pseudo
 
 set-current-plot "Gut bacteria"
 set-current-plot-pen "Pseudos"
 plot count pseudo
 set-current-plot-pen "Flora"
 plot sum [bacteria] of patches / count patches
 
 set-current-plot "Phosphate response"
 set-current-plot-pen "Phosphate"
 plot sum [phosphate] of patches / count patches
 set-current-plot-pen "PstS"
 plot sum [PstS] of pseudo / count pseudo
 set-current-plot-pen "phoR"
 plot sum [phoR] of pseudo / count pseudo
 set-current-plot-pen "phoB"
 plot sum [phoB] of pseudo / count pseudo
 set-current-plot-pen "phoB-Pi"
 plot sum [phoB-Pi] of pseudo / count pseudo
 
 set-current-plot "Mucous phosphate"
 set-current-plot-pen "mucous-phosphate"
 plot sum [phosphate] of patches / count patches
 set-current-plot-pen "lumen-phosphate"
 plot sum [phosphate-lumen] of patches / count patches

end

to make-movie

  ;; prompt user for movie location
  user-message "First, save your new movie file (choose a name ending with .mov)"
  let path user-new-file
  if not is-string? path [ stop ]  ;; stop if user canceled

  ;; run the model
  setup
  movie-start path
  movie-grab-view
  while [ticks < 251 ]
    [ go
      movie-grab-view 
      if ticks = 125
       [set background "bacteria"
       ]
      if ticks = 175
       [set background "permeability"
       ]
      if ticks = 225
      [set background "epi-cells"
      ]
    ]

  ;; export the movie
  movie-close
  user-message (word "Exported movie to " path)
end

to  data-collect
 if step = 1
   [print hour
    
    print sum [bacteria] of patches / count patches
   
    print count pseudo
    
    if hour = 36 and step = 2 
     [print " "]
   ]
 end

              
              
              
              
@#$#@#$#@
GRAPHICS-WINDOW
166
55
605
515
16
16
13.0
1
10
1
1
1
0
1
1
1
-16
16
-16
16
0
0
1
ticks

CC-WINDOW
5
569
1232
664
Command Center
0

BUTTON
231
10
294
43
go
go\n
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
166
10
229
43
setup
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SWITCH
3
10
129
43
random-runs
random-runs
0
1
-1000

MONITOR
302
10
364
55
step
step
17
1
11

MONITOR
367
10
429
55
hour
hour
17
1
11

CHOOSER
3
47
141
92
background
background
"mucous" "bacteria" "permeability" "quorum" "phosphate" "interferon" "adenosine" "inosine" "dynorphin" "epi-cells"
1

PLOT
818
10
1022
131
Barrier permeability
NIL
NIL
0.0
300.0
0.0
10.0
true
false
PENS
"PA1-lectin" 1.0 0 -2674135 true
"tight-junction" 1.0 0 -13345367 true

PLOT
1023
10
1223
131
Mucous phosphate
NIL
NIL
0.0
300.0
0.0
10.0
true
false
PENS
"mucous-phosphate" 1.0 0 -13345367 true
"lumen-phosphate" 1.0 0 -10899396 true

MONITOR
610
300
667
345
PstS
sum [PstS] of pseudo
17
1
11

MONITOR
669
300
726
345
phoB
sum [phoB] of pseudo
17
1
11

MONITOR
728
300
785
345
phoR
sum [phoR] of pseudo
17
1
11

MONITOR
787
300
844
345
phoB-Pi
sum [phoB-Pi] of pseudo
17
1
11

MONITOR
925
362
982
407
mvfr
sum [mvfr] of pseudo
17
1
11

MONITOR
846
300
903
345
i-mucin
sum [i-mucinase] of pseudo
17
1
11

MONITOR
11
506
70
551
pseudos
count pseudo
17
1
11

BUTTON
436
10
506
43
NIL
make-movie
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

MONITOR
511
10
596
55
movie-status
movie-status
17
1
11

SWITCH
12
470
115
503
data
data
0
1
-1000

MONITOR
73
508
130
553
epi-cells
count epi-cell
17
1
11

MONITOR
611
363
668
408
IFN
sum [interferon] of patches
17
1
11

MONITOR
671
363
728
408
oprF
sum [oprF] of pseudo
17
1
11

MONITOR
731
363
788
408
RhlRl
sum [i-RhlRI] of pseudo
17
1
11

MONITOR
790
363
847
408
luxbox
sum [luxbox] of pseudo\n
17
1
11

MONITOR
925
427
982
472
lecA
sum [lecA] of pseudo
17
1
11

MONITOR
984
427
1041
472
i-PA1
sum [i-PA1-lectin] of pseudo
17
1
11

MONITOR
1043
428
1100
473
PA1
sum [PA1-lectin] of patches
17
1
11

MONITOR
849
510
906
555
dynorph
sum [dynorphin] of patches
17
1
11

MONITOR
909
510
967
555
i-dynorph
sum [i-dynorphin] of pseudo
17
1
11

MONITOR
983
362
1040
407
TNA
sum [TNA] of pseudo
17
1
11

MONITOR
1041
362
1098
407
pqsABC
sum [pqsABCDE] of pseudo
17
1
11

MONITOR
1100
362
1157
407
i-PQS
sum [i-PQS] of pseudo
17
1
11

MONITOR
1158
362
1215
407
i-HQNO
sum [i-HQNO] of pseudo
17
1
11

TEXTBOX
612
288
762
306
Phosphate Response
11
0.0
1

TEXTBOX
612
348
762
366
Interferon Response
11
0.0
1

TEXTBOX
850
495
1000
513
Opioid Response
11
0.0
1

TEXTBOX
613
411
763
429
Adenosine Response
11
0.0
1

TEXTBOX
926
347
1076
365
MvfR pathway
11
15.0
1

MONITOR
611
427
668
472
adenosine
sum [adenosine] of patches
17
1
11

MONITOR
670
427
734
472
i-adenosine
sum [i-adenosine] of pseudo
17
1
11

MONITOR
736
427
796
472
deaminase
sum [adenosine-deaminase] of pseudo
17
1
11

MONITOR
798
427
856
472
i-inosine
sum [inosine] of pseudo
17
1
11

MONITOR
858
427
915
472
inosine
sum [p-inosine] of patches
17
1
11

TEXTBOX
926
411
1076
429
lecA pathway
11
15.0
1

SLIDER
12
263
164
296
initial-pseudo-population
initial-pseudo-population
0
100
100
1
1
NIL
HORIZONTAL

CHOOSER
12
299
163
344
Mode
Mode
"health" "stress" "ischemia-limited" "ischemia" "inflammation"
0

CHOOSER
12
349
162
394
epi-effect
epi-effect
"focus" "all"
1

PLOT
607
10
817
131
Gut Bacteria
NIL
NIL
0.0
300.0
0.0
200.0
true
false
PENS
"Pseudos" 1.0 0 -2674135 true
"Flora" 1.0 0 -13345367 true

SWITCH
3
98
156
131
Phosphate-deplete
Phosphate-deplete
1
1
-1000

SWITCH
3
134
156
167
Enteral-phosphate
Enteral-phosphate
1
1
-1000

SLIDER
12
397
162
430
smooth-colonies
smooth-colonies
0
10
0
1
1
NIL
HORIZONTAL

SLIDER
12
434
162
467
quorum-threshold
quorum-threshold
0
50
3
1
1
NIL
HORIZONTAL

MONITOR
1017
510
1092
555
quorum/patch
sum [quorum-signal] of patches / count patches
1
1
11

MONITOR
1094
510
1176
555
pseudo quorum
count pseudo with [quorum = true]
17
1
11

BUTTON
166
518
269
551
test ischemia
go\nif hour = 1 and step = 1\n[set mode \"ischemia\"]\nif hour = 1 and step >= 6\n[set mode \"health\"]\n
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
273
519
356
552
test phos
go\nset phosphate-deplete true\nif hour >= 3\n[set phosphate-deplete false]
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

PLOT
607
131
817
252
Phosphate Response
NIL
NIL
0.0
10.0
0.0
10.0
true
false
PENS
"phosphate" 1.0 0 -10899396 true
"PstS" 1.0 0 -13345367 true
"phoB" 1.0 0 -8630108 true
"phoR" 1.0 0 -5825686 true
"phoB-Pi" 1.0 0 -955883 true

BUTTON
361
518
476
551
test inflammation
go\nset mode \"inflammation\"
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

SWITCH
4
171
129
204
Iron-deplete
Iron-deplete
1
1
-1000

SWITCH
5
207
129
240
Enteral-iron
Enteral-iron
1
1
-1000

PLOT
835
146
1035
296
Iron
NIL
NIL
0.0
10.0
0.0
10.0
true
false
PENS
"iron" 1.0 0 -16777216 true
"iron-sense" 1.0 0 -13345367 true
"pyoverdin" 1.0 0 -955883 true

@#$#@#$#@
WHAT IS IT?
-----------
This section could give a general understanding of what the model is trying to show or explain.


HOW IT WORKS
------------
This section could explain what rules the agents use to create the overall behavior of the model.


HOW TO USE IT
-------------
This section could explain how to use the model, including a description of each of the items in the interface tab.


THINGS TO NOTICE
----------------
This section could give some ideas of things for the user to notice while running the model.


THINGS TO TRY
-------------
This section could give some ideas of things for the user to try to do (move sliders, switches, etc.) with the model.


EXTENDING THE MODEL
-------------------
This section could give some ideas of things to add or change in the procedures tab to make the model more complicated, detailed, accurate, etc.


NETLOGO FEATURES
----------------
This section could point out any especially interesting or unusual features of NetLogo that the model makes use of, particularly in the Procedures tab.  It might also point out places where workarounds were needed because of missing features.


RELATED MODELS
--------------
This section could give the names of models in the NetLogo Models Library or elsewhere which are of related interest.


CREDITS AND REFERENCES
----------------------
This section could contain a reference to the model's URL on the web if it has one, as well as any other necessary credits or references.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.0.4
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@