/**
Batch_pairwise_coexpression_analysis_for_48_and_72hpf_Platynereis_larvae.ijm
this macro merges gene expression scans for 48 or 72 hpf Platynereis larvae and shows the overlap 
(all against all) in white for the episphere as anterior view and the whole animal as lateral view
to run this macro use Fiji http://fiji.sc/
all input files have to be in the same folder, and have to be the same size, generated by aligning 
your scans to the 48 or 72 hpf Dapi template provided in the paper by Asadulina et al. 2012
by Gaspar Jekely, 2012
*/

G_Sdir=getDirectory("Choose the directory where the files are");
list=getFileList(G_Sdir);
stage = getNumber("Stage (48 or 72): ", stage);  //the stage (48 or 72 hpf) has to be defined for the cropping parameters


//depending on the stage, the cropping parameters are assigned these values
if (stage==72){rect1=61; rect2=92; rect3=320; rect4=470; rect5=0; rect6=0; rect7=451; rect8=241;rect9=0; rect10=0; rect11=451; rect12=241; rect13=68; rect14=0; rect15=315; rect16=315;}
else if (stage==48){rect1=65; rect2=35; rect3=400; rect4=400; rect5=50; rect6=82; rect7=400; rect8=135; rect9=50; rect10=82; rect11=400; rect12=135; rect13=22; rect14=38; rect15=400; rect16=400;}
else {print ("Stage has to be either 48 or 72!"); exit;}


//this loops goes through all the image files in the selected directory	
for (k=0; k<list.length; k++)
	{
	//this loop goes through all the image files in the selected directory	
	for (i=k; i<list.length; i++)
		{	
		fullpath_image1=G_Sdir + list[k];
		open(fullpath_image1);
		img_title1 = getTitle();
		rename("channel1"); //channel1 will be the reference image
		
		fullpath_image2=G_Sdir + list[i];
		open(fullpath_image2);
		img_title2 = getTitle();
		rename("channel2"); //channel2 will be the image we compare to the reference

		fullpath_image_out1=G_Sdir + "Montage";
		fullpath_image_out2=G_Sdir + "Stack";

		outfilename=img_title1+"_red "+img_title2+"_cyan";
		
		////////////////////////////////////////////////////////////////////////
		//generating the ventral view overlap
		////////////////////////////////////////////////////////////////////////


		//contrasting, rotating, duplicating, thresholding and z-projecting channel1
		selectWindow("channel1");
		run("Enhance Contrast...", "saturated=0.01 process_all use"); //contrast enhancement to the same saturation value for all stacks is important for the later thresholding
		run("Duplicate...", "title=channel1_dupl duplicate range=1-600");
		selectWindow("channel1_dupl");
		run("TransformJ Rotate", "z-angle=0.0 y-angle=0 x-angle=15 interpolation=linear background=0.0 adjust"); //performs a 15 degree rotation along the x axis to get the best ventral view
		selectWindow("channel1_dupl rotated");
		rename("channel1_dupl_rotated");
		channel1_slices=nSlices();
		run("Z Project...", "start=1 stop=channel1_slices projection=[Max Intensity]");
		//thresholding of channel1
		selectWindow("channel1_dupl_rotated");
		run("Smooth", "stack");
		//run("Threshold...");
		setAutoThreshold("Yen stack"); //for thresholding the Yen method is used, this can be changed to Otsu, MaxEntropy or other methods, depending on the samples
		run("Convert to Mask", " ");
		selectWindow("channel1_dupl");
		close();

		//contrasting, rotating, duplicating, thresholding and z-projecting channel2
		selectWindow("channel2");
		run("Enhance Contrast...", "saturated=0.01 process_all use"); //contrast enhancement to the same saturation value for all stacks is important for the later thresholding
		run("Duplicate...", "title=channel2_dupl duplicate range=1-600");
		selectWindow("channel2_dupl");
		run("TransformJ Rotate", "z-angle=0.0 y-angle=0 x-angle=15 interpolation=linear background=0.0 adjust");
		selectWindow("channel2_dupl rotated");
		rename("channel2_dupl_rotated");
		selectWindow("channel2_dupl_rotated");
		channel2_slices=nSlices();
		run("Z Project...", "start=1 stop=channel2_slices projection=[Max Intensity]");
		selectWindow("channel2_dupl_rotated");
		run("Smooth", "stack");
		//run("Threshold...");
		setAutoThreshold("Yen stack"); //for thresholding the Yen method is used, this can be changed to Otsu, MaxEntropy or other methods, depending on the samples
		run("Convert to Mask", " ");
		selectWindow("channel2_dupl");
		close();

		//calculating the overlap between the thresholded stacks of channel1 and 2
		imageCalculator("Max create stack", "channel1_dupl_rotated","channel2_dupl_rotated");
		//run("Image Calculator...", "image1=channel1 operation=Min image2=channel2 create stack");
		selectWindow("Result of channel1_dupl_rotated");
		channel1_slices=nSlices();
		//create projection of the coexpression area
		run("Z Project...", "start=1 stop=channel1_slices projection=[Min Intensity]"); //here we define the pixels where both channels have a signal 
		selectWindow("MIN_Result of channel1_dupl_rotated");
		run("Smooth");
		rename("overlap");
		run("Invert");

		//merging the original images with the coexpression image shown in white
		run("Merge Channels...", "c1=MAX_channel1_dupl_rotated c2=MAX_channel2_dupl_rotated c3=MAX_channel2_dupl_rotated c4=overlap create");
		selectWindow("Composite");
		run("RGB Color");
		selectWindow("Composite");
		close();
		selectWindow("Composite (RGB)");
		rename(outfilename);
		makeRectangle(rect1, rect2, rect3, rect4);
		run("Crop");
		
		//closing unused images
		selectWindow("channel1_dupl_rotated");
		close();
		selectWindow("Result of channel1_dupl_rotated");
		close();
		selectWindow("channel2_dupl_rotated");
		close();
		
		////////////////////////////////////////////////////////////////////////
		//generating the apical view overlap
		////////////////////////////////////////////////////////////////////////

		//cropping, contrasting, rotating, duplicating, thresholding and z-projecting channel1
		selectWindow("channel1");
		makeRectangle(rect5, rect6, rect7, rect8);
		run("Crop");
		selectWindow("channel1");
		run("TransformJ Rotate", "z-angle=0.0 y-angle=0 x-angle=90 interpolation=linear background=0.0 adjust");
		selectWindow("channel1 rotated");
		rename("channel1_rotated");
		channel1_slices=nSlices();
		run("Z Project...", "start=1 stop=channel1_slices projection=[Max Intensity]");
		selectWindow("channel1_rotated");
		run("Smooth", "stack");
		//run("Threshold...");
		setAutoThreshold("Yen stack"); //for thresholding the Yen method is used, this can be changed to Otsu, MaxEntropy or other methods, depending on the samples
		run("Convert to Mask", " ");
		selectWindow("channel1");
		close();

		//cropping, contrasting, rotating, duplicating, thresholding and z-projecting channel2
		selectWindow("channel2");
		makeRectangle(rect9, rect10, rect11, rect12);
		run("Crop");
		selectWindow("channel2");
		run("TransformJ Rotate", "z-angle=0.0 y-angle=0 x-angle=90 interpolation=linear background=0.0 adjust");
		selectWindow("channel2 rotated");
		rename("channel2_rotated");
		selectWindow("channel2_rotated");
		channel2_slices=nSlices();
		run("Z Project...", "start=1 stop=channel2_slices projection=[Max Intensity]");
		selectWindow("channel2_rotated");
		run("Smooth", "stack");
		//run("Threshold...");
		setAutoThreshold("Yen stack"); //for thresholding the Yen method is used, this can be changed to Otsu, MaxEntropy or other methods, depending on the samples
		run("Convert to Mask", " ");
		selectWindow("channel2");
		close();

		//calculating the overlap between the thresholded stacks of channel1 and 2
		imageCalculator("Max create stack", "channel1_rotated","channel2_rotated");
		//run("Image Calculator...", "image1=channel1 operation=Min image2=channel2 create stack");
		selectWindow("Result of channel1_rotated");
		channel1_slices=nSlices();
		//create projection of the coexpression area
		run("Z Project...", "start=1 stop=channel1_slices projection=[Min Intensity]"); //here we define the pixels where both channels have a signal
		selectWindow("MIN_Result of channel1_rotated");
		run("Smooth");
		rename("overlap");
		run("Invert");
		
		//merging the original images with the coexpression image shown in white
		run("Merge Channels...", "c1=MAX_channel1_rotated c2=MAX_channel2_rotated c3=MAX_channel2_rotated c4=overlap create");
		selectWindow("Composite");
		run("RGB Color");
		selectWindow("Composite");
		close();
		selectWindow("Composite (RGB)");
		rename(outfilename);
		makeRectangle(rect13, rect14, rect15, rect16);
		run("Crop");
		
		//create projection of the coexpression area
		selectWindow("channel1_rotated");
		run("Z Project...", "start=1 stop=channel1_slices projection=[Min Intensity]"); //here we define the pixels where both channels have a signal
		selectWindow("Result of channel1_rotated");
		close();
		selectWindow("channel2_rotated");
		channel2_slices=nSlices();
		run("Z Project...", "start=1 stop=channel2_slices projection=[Min Intensity]"); //here we define the pixels where both channels have a signal
		selectWindow("channel2_rotated");
		close();
		selectWindow("channel1_rotated");
		close();
		
		//closing unused images
		selectWindow("MIN_channel1_rotated");
		close();
		selectWindow("MIN_channel2_rotated");
		close();
		}
	}


//create the stack of all gene pairs
run("Images to Stack", "method=[Copy (center)] name=Stack title=[] use");
selectWindow("Stack");
sliceNumber=nSlices;
print(sliceNumber);

//create the montage from the stack
run("Colors...", "foreground=white background=white selection=yellow");
run("Make Montage...", "columns=6 rows="+sliceNumber/6+" scale=1 first=1 last="+sliceNumber+" increment=1 border=5 font=20 label");
selectWindow("Montage");
setMinAndMax(50, 150); //subtract some background and increase the contrast
run("Apply LUT", "stack");
saveAs("tiff", fullpath_image_out1); //save Montage
selectWindow("Stack");
setMinAndMax(50, 150); //subtract some background and increase the contrast
run("Apply LUT", "stack");
saveAs("tiff", fullpath_image_out2); //save stack