title_2=File.openDialog("Choose File");
open(title_2);
dir=File.getParent(title_2)+File.separator;
name=File.nameWithoutExtension();
print(dir+name+".xls");
run("16-bit");
run("Despeckle");
run("Subtract Background...", "rolling=40");
original_title=getTitle();
run("Duplicate...", " ");
selectImage(2);
rename("Duplicate");
selectWindow("Duplicate");
setTool("rectangle");
waitForUser("Identify ROIs, adding each to ROI manager with 't' button");

roiManager("Combine");
setBackgroundColor(0, 0, 0);
run("Clear Outside");
run("Select None");
roiManager("Reset");
run("Find Maxima...", "noise=2 output=[Maxima Within Tolerance]");
run("Create Selection");

roiManager("Add");
roiManager("Select", 0);
roiManager("Split");
roiManager("Select", 0);
roiManager("Delete");
close();
counter=0;
roiManager("Deselect");
objects=roiManager("Count");
setColor(255,1,1);
setLineWidth(4);
for(ii=0; ii<objects; ii++){
		roiManager("Select", ii);
 		run("To Selection");
 		Dialog.create("Answer");
  		Dialog.addCheckbox("Keep?", false);
  		Dialog.show();
  		response = Dialog.getCheckbox();
  		if (response == true){
  			run("Find Maxima...", "noise=2 output=[Point Selection]");
  			getSelectionCoordinates(x,y);
			run("Select None");
			inten1=getPixel(x[0],y[0]);
			setResult("Intensity",counter,inten1);
  			setResult("X1",counter,x[0]);
			setResult("Y1",counter,y[0]);
			counter++;
			drawOval(x[0]-10,y[0]-10,20,20);
  		}
	}	

updateResults();
selectWindow("Results");
IJ.renameResults(name);
saveAs("Results",dir+name+"_manual"+".xls");
selectWindow(name+"_manual"+".xls");
run("Close");
run("Close All");
roiManager("Reset");