public class Chart{
  
    //private variables
      
      
      //axis information
      private final int majorTickSize = 10;
      private final int minorTickSize = 5;
      
      private boolean ySet;
      private float ymin;
      private float ymax;
      private float ymajor;
      private float yminor;
      private String ylabel;
      private String xlabel;
      
      private int gap; //adds a gap between bars
      
      //color information
      private color bkground;
      
      //distribution info
      
      //draw information
      
      private ArrayList<ChartObject> objects;
      private int m_x;
      private int m_y;
      private int m_w;
      private int m_h;
      private int sigFigs = 3;

/******************************************
  Constructor
******************************************/

    public Chart(int x,int y,int w,int h){
      ySet = false;
      objects = new ArrayList<ChartObject>();
      bkground = color(255);
      m_x = x;
      m_y = y;
      m_w = w;
      m_h = h;
    }//end GradientChart

 
/******************************************
  Draw Methods
******************************************/

     public void draw(){
      noStroke();
      fill(bkground);
      rect(m_x,m_y,m_w,m_h); 
      drawAxes();
      
      if(objects.size()>0 && ySet){
        int perObj = floor((m_w-majorTickSize-textWidth(parseLabel(ymax)))/objects.size());
        int objWidth = perObj-(2*gap);
        int curX = m_x+majorTickSize+gap+ceil(textWidth(parseLabel(ymax)));
        
        for(ChartObject anObj:objects){
          anObj.draw(curX,objWidth,m_y+m_h-majorTickSize,m_y,ymin,ymax); 
          curX+=perObj;
        }//end for
      }//end if
      
    }//end draw
    
    public void drawAxes(){
      stroke(0);
      strokeWeight(1);
      if(ySet){
        
        if(ylabel!=null){
          pushMatrix();
          fill(0);
          stroke(0);
          translate(m_x-textAscent()-25, m_y-majorTickSize+(m_h/2)+(textWidth(ylabel)/2.0));
          rotate(-HALF_PI);
          text(ylabel,0,0);
          popMatrix();
        }//end if
        float minorTicks = (ymax-ymin)/yminor;
        float minorDelta = map(yminor,0,ymax-ymin,0,m_h-majorTickSize);
        
        float cury = m_y+m_h-majorTickSize;
        for(int i = 0;i<minorTicks;i++){
          stroke(0);
          line(m_x+majorTickSize,cury,m_x+majorTickSize-minorTickSize,cury);
          stroke(0,32);
          line(m_x+majorTickSize,cury,m_x+m_w,cury);
          cury-=minorDelta;
        }
        
        stroke(0);
        float majorTicks = (ymax-ymin)/ymajor;
        float majorDelta = map(ymajor,0,ymax-ymin,0,m_h-majorTickSize);
        
        cury = m_y+m_h-majorTickSize;
        for(int i = 0;i<=majorTicks;i++){
          line(m_x,cury,m_x+majorTickSize,cury);
          stroke(0);
          fill(0);
          text(parseLabel(ymajor*i + ymin),m_x-textWidth(parseLabel(ymajor*i + ymin)+"")-majorTickSize,cury+5);
          cury-=majorDelta;
        }
        
        if(xlabel!=null){
          fill(0);
          stroke(0);
          text(xlabel,m_x+majorTickSize+(m_w/2.0)-(textWidth(xlabel)/2.0),m_y+m_h+(3.5*textAscent())+5);
        }
        
        line(m_x+majorTickSize,m_y,m_x+majorTickSize,m_y+m_h-majorTickSize);
        line(m_x+majorTickSize,m_y+m_h-majorTickSize,m_x+m_w,m_y+m_h-majorTickSize);
      }//end if
      
    }//end drawAxes;
    

/******************************************
  Setters
******************************************/
  
    public void setBackground(color newbkground){
      bkground = newbkground;
    }//end setBackGround

    public void setAxis(float minimum,float maximum,float majorTick,float minorTick){   
           ymin = minimum;
           ymax = maximum;
           ymajor = majorTick;
           yminor = minorTick;
           ySet = true;
    }//end setAxis
    
    public void setAxis(String label,float minimum,float maximum,float majorTick,float minorTick){   
           ylabel = label;
           ymin = minimum;
           ymax = maximum;
           ymajor = majorTick;
           yminor = minorTick;
           ySet = true;
    }//end setAxis
    
    public void setGap(int newGap){
      gap = newGap;
    }//end 
    
    public void setSignificantFigures(int newsigfig){
      sigFigs = newsigfig;
    }
    
    public void setYLabel(String label){
      ylabel = label;
    }//end setLabel
    
    public void setXLabel(String label){
      xlabel = label;
    }//end setXLabel
        
    public void addBarGroup(BarGroup aBarGroup){
      objects.add(aBarGroup);
    }//end addBarGroup
    
    public void addObject(ChartObject aBar){
      objects.add(aBar);
    }//end addObject
    
    public void addBar(Bar aBar){
      objects.add(aBar);
    }//end addBar
    
    public void addBar(float mean,color barColor,float margin,int n){
      objects.add(new Bar(mean,barColor,margin,n));
    }//end addBar
    
    public void addBar(float mean,color barColor,float margin,int n,String label){
      objects.add(new Bar(mean,barColor,margin,n,label));
    }//end addBar
    
    public void addGradient(Gradient aBar){
      objects.add(aBar);
    }//end addGradient
    
    public void addGradient(float mean,color barColor,float margin,int n){
      objects.add(new Gradient(mean,barColor,margin,n));
    }//end addGradient
    
    public void addGradient(float mean,color barColor,float margin,int n,String label){
      objects.add(new Gradient(mean,barColor,margin,n,label));
    }//end addGradient
    
    public void addViolin(Violin aBar){
      objects.add(aBar);
    }//end addViolin
    
    public void addViolin(float mean,color barColor,float margin,int n){
      objects.add(new Violin(mean,barColor,margin,n));
    }//end addViolin
    
    public void addViolin(float mean,color barColor,float margin,int n,String label){
      objects.add(new Violin(mean,barColor,margin,n,label));
    }//end addViolin
    
    public void addDot(float mean,color barColor,float margin,int n){
     objects.add(new Dot(mean,barColor,margin,n));
    }//end addBar
    
    public void addDot(float mean,color barColor,float margin,int n,String label){
      objects.add(new Dot(mean,barColor,margin,n,label));
    }//end addBar  
  
    public void addDot(Dot aBar){
      objects.add(aBar);
    }
    
    public void addBox(float mean,color barColor,float margin,int n){
     objects.add(new Box(mean,barColor,margin,n));
    }//end addBar
    
    public void addBox(float mean,color barColor,float margin,int n,String label){
      objects.add(new Box(mean,barColor,margin,n,label));
    }//end addBar  
  
    public void addBox(Box aBar){
      objects.add(aBar);
    }
    
/******************************************
  Helper Methods
******************************************/

  private String parseLabel(float label){
    if (label-int(label)==0.0){
      return int(label)+"";
    }
    else if(label<1){
      return (label+"").substring(1,min((label+"").length(),1+sigFigs));
    }
    else{
     return (label+"").substring(0,min((label+"").length(),(label+"").indexOf('.')+sigFigs));
    }
  }
}//end class