clear
set more off

use "impact_ofSIAs_data.dta"

**Descriptive statistics
levelsof isocode, local(levels)
foreach l of local levels {
foreach var of varlist rural order primary secondary higher electricity female rainy vaccines exposure ageatfirst {
di "`l'"
sum `var' if isocode=="`l'"
}
  }
  
********************************************************************************
  
*Global for control variables
global xvar rural order primary secondary higher electricity female rainy i.birth_yr
  
**Main results
foreach l of local levels {
di "`l'"
ivregress 2sls vaccines $xvar  sss* (exposure = ageatfirst) if isocode=="`l'", cluster(sur_reg) first
}

********************************************************************************

*Ivprobit
foreach l of local levels {
di "`l'"
ivprobit vaccines $xvar sss* (exposure = ageatfirst) if isocode=="`l'", vce(cluster sur_reg)
margins, dydx(exposure) predict(pr) atmean
}

********************************************************************************

*Children 12-23 months
foreach l of local levels {
di "`l'"
ivregress 2sls vaccines $xvar sss* (exposure = ageatfirst) if isocode=="`l'" & age_m<24, cluster(sur_reg) first
}

********************************************************************************

*Vaccines by age one
foreach l of local levels {
di "`l'"
ivregress 2sls vaccines_12m $xvar sss* (exposure12m = ageatfirst12m) if isocode=="`l'", cluster(sur_reg) first
}

********************************************************************************

*Individual vaccines
foreach l of local levels {
di "`l'"
ivregress 2sls dpt3 $xvar  sss* (exposure = ageatfirst) if isocode=="`l'", cluster(sur_reg) first
ivregress 2sls measles $xvar  sss* (exposure = ageatfirst) if isocode=="`l'", cluster(sur_reg) first
ivregress 2sls bcg $xvar  sss* (exposure = ageatfirst) if isocode=="`l'", cluster(sur_reg) first
}

********************************************************************************

*Including non-NIDs for Senegal & Cote d'Ivoire

ivregress 2sls vaccines $xvar  sss* (exposure_nonNID = ageatfirst_nonNID) if isocode=="senegal", cluster(sur_reg) first
ivregress 2sls vaccines $xvar  sss* (exposure_nonNID = ageatfirst_nonNID) if isocode=="cote d'ivoire", cluster(sur_reg) first